【IntelliJ IDEA工具】spring boot使用JPA自动生成实体类（数据库表逆向工程自动生成带注释的实体类）

1、maven依赖：

        <!-- JPA，用于自动生成表结构 -->
        <dependency>
          <groupId>org.springframework.boot</groupId>
          <artifactId>spring-boot-starter-data-jpa</artifactId>
        </dependency>
        <dependency>
          <groupId>javax.persistence</groupId>
          <artifactId>persistence-api</artifactId>
          <version>1.0.2</version>
        </dependency>

        <dependency>
          <groupId>org.projectlombok</groupId>
          <artifactId>lombok</artifactId>
          <version>${lombok.version}</version>
          <optional>true</optional>
        </dependency>

        <dependency>
          <groupId>mysql</groupId>
          <artifactId>mysql-connector-java</artifactId>
          <version>5.1.47</version>
        </dependency>

2、idea添加数据库连接

3、连接上数据库，选中任意表，右击，找到schema目录下的Generate POJOs.groovy文件:

4、Generate POJOs.groovy文件配置如下：

import com.intellij.database.model.DasTable
import com.intellij.database.util.Case
import com.intellij.database.util.DasUtil
import java.text.SimpleDateFormat
/*
 * Available context bindings:
 *   SELECTION   Iterable<DasObject>
 *   PROJECT     project
 *   FILES       files helper
 */
packageName = ""
typeMapping = [
  (~/(?i)tinyint|smallint|mediumint|int/)      : "Integer",
  (~/(?i)bigint/)                             : "Long",
  (~/(?i)bool|bit/)                        : "Boolean",
  (~/(?i)float|double|decimal|real/)       : "BigDecimal",
  (~/(?i)datetime|timestamp|date|time/)    : "Date",
  (~/(?i)blob|binary|bfile|clob|raw|image/): "InputStream",
  (~/(?i)/)                                : "String"
]

FILES.chooseDirectoryAndSave("Choose directory", "Choose where to store generated files") { dir ->
  SELECTION.filter { it instanceof DasTable }.each { generate(it, dir) }
}

def generate(table, dir) {
  def className = javaName(table.getName(), true)
  def fields = calcFields(table)
  packageName = getPackageName(dir)
  new File(dir, className + ".java").withPrintWriter("utf-8") { out -> generate(out, className, fields, table) }
}

def generate(out, className, fields, table) {
  out.println "package $packageName"
  out.println ""
  out.println "import lombok.Data;"
  out.println "import javax.persistence.Table;"
  out.println "import javax.persistence.Column;"
  out.println "import java.io.Serializable;"
  /* 引入数据包 */
  Set types = new HashSet()
  fields.each() {
    types.add(it.type)
  }
  if (types.contains("Date")) {
    out.println "import java.util.Date;"
  }
  if (types.contains("BigDecimal")) {
    out.println "import java.math.BigDecimal;"
  }
  if (types.contains("InputStream")) {
    out.println "import java.io.InputStream;"
  }
  out.println ""
  out.println "/**\n "+
          "* @author <a href=\"mailto:Tastill@**.cn\">Tastill</a> \n " +
          "* @version " + new SimpleDateFormat("yyyy-MM-dd HH:mm:ss").format(new Date()) + "\n " +
          "* @description " + table.getName() + "\n" +
          "*/"
  out.println ""
  out.println "@Table(name = \"" + table.getName() + "\")"
  out.println "@Data"
  out.println "public class $className implements Serializable{"
  out.println ""
  out.println genSerialID()
  fields.each() {
    // 输出注释
    if (isNotEmpty(it.comment)) {
      out.println "  /**"
      out.println "   * ${it.comment.toString()}"
      out.println "   */"
    }
    /*if ((it.annos+"").indexOf("[@Id]") >= 0) out.println "@Id"
    if (it.annos != "") out.println "   ${it.annos.replace("[@Id]", "")}"*/
    if (it.annos != "") out.println "  ${it.annos}"
    // 输出成员变量
    out.println "  private ${it.type} ${it.name};"
  }
  out.println ""
  /*fields.each() {
    out.println ""
    out.println "  public ${it.type} get${it.name.capitalize()}() {"
    out.println "    return ${it.name};"
    out.println "  }"
    out.println ""
    out.println "  public void set${it.name.capitalize()}(${it.type} ${it.name}) {"
    out.println "    this.${it.name} = ${it.name};"
    out.println "  }"
    out.println ""
  }*/
  out.println "}"
}

def calcFields(table) {
  DasUtil.getColumns(table).reduce([]) { fields, col ->
    def spec = Case.LOWER.apply(col.getDataType().getSpecification())
    def typeStr = typeMapping.find { p, t -> p.matcher(spec).find() }.value
    fields += [[
                 name : javaName(col.getName(), false),
                 type : typeStr,
                 comment: col.getComment(),
                 annos   : "@Column(name = \"" + col.getName() + "\" )"]]
  }
}

def javaName(str, capitalize) {
  def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
    .collect { Case.LOWER.apply(it).capitalize() }
    .join("")
    .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
  capitalize || s.length() == 1? s : Case.LOWER.apply(s[0]) + s[1..-1]
}

// 获取包所在文件夹路径
def getPackageName(dir) {
  return dir.toString().replaceAll("\\\\", ".").replaceAll("/", ".").replaceAll("^.*src(\\.main\\.java\\.)?", "") + ";"
}

//判断是否为空
def isNotEmpty(content) {
  return content != null && content.toString().trim().length() > 0
}

//生成序列化的serialVersionUID
static String genSerialID() {
  return "\tprivate static final long serialVersionUID =  " + Math.abs(new Random().nextLong()) + "L;"
}

5、选择待生成实体表，

6、选择文件存放路径

7、生产效果如下

package cn.**.**.**.common.model;

import lombok.Data;
import javax.persistence.Table;
import javax.persistence.Column;
import java.io.Serializable;

/**
 * @author <a href="mailto:Tastill@**.cn">Tastill</a> 
 * @version 2020-09-15 17:04:59
 * @description **_**_jjr
*/

@Table(name = "**_**_jjr")
@Data
public class ***Jjr implements Serializable{

	private static final long serialVersionUID =  5137725334275023247L;
  /**
   * 主键
   */
  @Column(name = "ID" )
  private String id;
  /**
   * 节假日（yyyyMMdd）
   */
  @Column(name = "JJR" )
  private String jjr;

}